start

On my boatride back to my hometown after a failed music career, my insomnia seems to have finally ended, yet the world I have woken up to seems so different than the one I know of, and it talks to me in it's distinct voice known only to me.

Lost at the MarketBy Nynym

For instructions, click:

Be prepared to take on your dream.

I'm carrying:

Save game as:

Really restart this game?

Display options

font:

font size:

Print room title in scroller:

Always

Landscape only

Never

List objects in scroller

Always

Landscape only

Never

This game was made with gruescript.

game Lost at the Market
id LATM
author Nynym
version 0.1
examine on
conversation on
wait off

person 1

say On my boatride back to my hometown after a failed music career, my insomnia seems to have finally ended, yet the world I have woken up to seems so different than the one I know of, and it talks to me in it's distinct voice known only to me.
say

status {$room}
carry A_lyrics_sheet

color statusbar_background burlywood #darksalmon
color conversation_text black
color statusbar_text white
color conversation_button sienna #blanchedalmond
color main_background cadetblue #tan #burlywood 
color conversation_button_text white
color main_text black       
color examine_button bisque
color main_prompt moccasin
color examine_button_text white
color main_text_old gray          
color inventory_background darksalmon
color main_prompt_old whitesmoke
color inventory_text white
color instructions_button sandybrown     
color inventory_button saddlebrown
color instructions_button_text white  
color inventory_button_text white
color room_background silver         
color inventory_inactive_text sandybrown
color room_text black white              
color save_background bisque
color room_button saddlebrown              
color save_button saddlebrown
color room_button_text white       
color save_button_text white
color conversation_background moccasin
color page_background cadetblue #tan #lightpink

room start Be prepared to take on your dream.
dir Start dark
dir About about
dir Instructions inst
tags start

room inst Instructions
dir Start dark
dir About about
prop desc Please refer to the text file in the link <a href=https://ronynn.github.io/Game-Jam-Submissions/LATM/walkthrough.txt>walkthrough.txt</a>

room about About
dir Start dark
dir Instructions inst
prop desc To learn more about the design choices and processes behind this interactive fiction piece please visit <a href="https://ronynn.github.io/Game-Jam-Submissions/LATM/walkthrough.txt"> walkthrough.txt </a>

verb go About
say ------------------------
say <i>Market: to engage in the commercial promotion, sale, or distribution of
say
say Market: the customers for a particular product or service<i>
say ------------------------
say

room dark A dark room
prop desc A fog covered room, unseen yet familiar, in your heart you knew you will be waking up here, yet you kept that thought aside. Still it is comforting to be here, but there's nothing to do.
north light
dir Who_am_I whoamI

thing A_lyrics_sheet
tags portable
desc A lyrics sheet but the lyrics seem unclear, perhaps you can read it later.
cverbs Bring_it_Closer

verb Bring_it_Closer
eq $vc 0
say It makes no difference.

verb Bring_it_Closer
eq $vc 1
say ------------------------------------
say So much to say, so much to speak of,
say So many words forming it's congestion.
say Say what you want but I will pass through
say To be or not to be that is the question.
say ------------------------------------

proc lyrics
write A_lyrics_sheet.desc The lines are readable now.
add vc 1

room whoamI Who am I
prop desc Throughout the shade you find yourself in front of a mirror, yet you only see an image vaguely resembling you, ever transforming.
dir reach_for_the_mirror mirror

room mirror A mirror
prop desc You see your own reflection in the mirror, but you look older.
north light

proc go reach_for_the_mirror
say You stand closer to the mirror, the person infront of you seems sad, it stands back for a second as it fades away into the fog, all you can see now is your own reflection, but you seem to have aged.

room light A white room
prop desc You are now in a big bright room, you see a beautiful white tree, a white tree within a white room, a beautiful white room that you will never encounter again in your dreams. But you are happy to have seen such a sight, and happy even if it was just a dream.
north beach
dir the_dark_room dark
dir the_mirror mirror

room beach The beach
prop desc You are at the beach. You see an old gentleman sitting by the ocean.

thing sand_castle 
desc Once in a while you see something like this and wonder what your dad would say, the point in building sand castles that are here waiting to be swept away by the ocean is the same dream that keeps the world moving, yet can anyone move the ocean?
loc beach
verbs break

verb break
prompt knock on castle
say One swift kick to the castle and it turns back to sand. You don't feel happy about it.
goto aske

thing oldman Elderly Man
desc An elderly gentleman staring into the endless ocean.
loc beach
tags alive male conversation
prop start_conversation He pauses from staring at the ocean, and looks at you. "Perhaps I was the one at fault" he murmurs. You keep staring hoping he would say something more but he didn't.
prop end_conversation He sighs and continues his silent stare.

setverb ask_oldman Beach
verb ask_oldman Beach
say "I think we are staring at the same thing", he answers.
assign npc oldman

setverb ask_oldman Ocean 
verb ask_oldman Ocean
say "It's serene" he answers, "perhaps to a disappointing extent."

room aske A question to answer
prop desc Why do we dream when we know we might never reach those aspirations?
dir I_dont_know Wake_Up

room Wake_Up To wake up or not to
prop desc If those dreams are never to be reached, then wake up!

thing An_Alarm_Clock Ringgggg....!!
desc An object, a symbol, make this dream end!
loc Wake_Up
verbs Hit

verb Hit An_Alarm_Clock
goto roof

#-------------------------------

room roof A roof with great sights of the surrounding buildings
prop desc You just woke up at the roof of your apartment after a nice winter noon nap. "Oops, I did it again" you smirk under your facemask. The door to the stairs is closed, you could open it with a stick.
south tanks

room tanks The watertanks
prop desc This is where the water tanks of the apartment building are kept, one is right in front of you. Others are a bit harder to get to.
north roof

room stairs The stairs
prop desc Seems a bit too long. Almost neverending, but you can only go up. A poster for a music concert seems to be handpainted on the wall, what makes someone a star?
up bathroom

thing poster A poster
desc Handpainted, good amount of effort seems to have gone into it.
loc stairs

verb go up
loc stairs
say Perhaps a dream is nothing but a trap to one's goals, but those really your goals if you are not the ones to set them.
hide rope
hide stick

room alley A narrow alley.
north stairs 
prop desc A narrow alleyway with a poster for a music concert. The star of the show seems a bit unclear to you. You can take the stairs to the north.

thing dish_antenna
desc It seems pretty sturdy. You can't send morse code to your friends with it, although you have never tried extra terrestrial communication.
loc roof

thing rope
desc A pretty sturdy rope, used for hanging clothes perhaps.
loc tanks
tags portable
cverbs tie

verb tie rope
at roof
say You tied the rope to the dish antenna, it seems safe to climb down to the alley below.
put tied_rope roof
hide rope

verb tie rope
at watertank
say I tied this rope between two water tanks, it will surely be useful to someone trying to hang and dry their clothes here, not useful to me though.
hide rope

thing tied_rope
desc This rope has been tied to the dish antenna and seems safe to be used
verbs climb_down

verb climb_down tied_rope
at roof
goto alley
say Whoosh! There I go

thing alley_rope
loc alley
verbs climb_back_up

verb climb_back_up alley_rope
goto roof
say I don't know what I am doing to be honest, if this wasn't a dream I would look confused.

thing watertank 
desc This one might be the one sending water to your apartment. 
loc tanks
verbs open

verb open watertank
say You see a bulb inside held by a stick, it keeps the water from overflowing, you can take it out then open the tank again to put it back, you might need it right now.
bring stick tanks

thing stick
desc This stick was holding the bulb on the water tank
tags portable takeable
cverbs poke

verb poke stick
!at roof
say There's no place to poke the stick

verb poke stick
at roof
say The door to the stairs is now open, you are now at the stairs. But you can't see the roof.
hide stick
hide rope
goto stairs

#---------------------------------

room bathroom A bathroom
prop desc You seem to have locked yourself in this windowless bathroom

thing toiletseat
desc Seems recently clean, almost shining.
loc bathroom
tags portable

setverb take toiletseat
verb take toiletseat
!has toiletseat unbolted
say It's bolted to the toilet.

setverb unbolt toiletseat
!has toiletseat unbolted
held wrench

verb unbolt toiletseat
say It comes loose.
tag toiletseat unbolted
put Hole bathroom: A hole appears on the bathroom floor.

thing Hole 
desc You see a hole on the floor, it seems to be going somewhere
verbs Go_Through

verb Go_Through Hole
goto secondBathroom
try notdream
hide wrench

thing wrench
desc A slightly rusted wrench, nothing out of ordinary about it.
tags portable
loc bathroom

thing hammerhoid_cream
desc Used for pain relief
loc bathroom
tags portable
cverbs apply

verb apply hammerhoid_cream
say You feel much relaxed.
add hm 1
run count

proc count
eq $hm 3
say You ran out of hammeroid cream
hide hammerhoid_cream

#-----------------------------------
room secondBathroom In that bathroom again.
prop desc It's the same bathroom but everything seems much more clearer, and it smells like butterscotch.
north changingRoom

proc notdream
say It doesn't feels that dreamlike anymore, this seems to be a memory of yours, your last bet at a music career, and your drummer is half asleep in the bathroom
hide toiletseat

room changingRoom A changing room
prop desc You manager arranged a room for your band while the other performers are just waiting backstage.
west corridor
south secondBathroom

room corridor A corridor
prop desc A recently cleaned corridor with that lime smell.
north stage
south exit
east changingRoom

room stage Main Stage
south corridor
east backstage
prop desc People are waiting for the next performance, although no one seems excited watching you standing here.

room backstage All the contestants are waiting here for their turns.
west stage

thing woman An organiser 
desc An organiser catches your attention, she is occasionally staring your way.
loc backstage
tags alive woman conversation
prop start_conversation She looks at you curiously
prop end_conversation She looks away

setverb ask_woman Performance
verb ask_woman Performance
say "Ya I do have a spare guitar, Ed told me the the guitarist is wearing gloves of some kind", you get a rough idea of what you need to do.

setverb ask_woman A_Guitar
verb ask_woman A_Guitar
visible gloves
say "There you go, now go play it on the stage", the organiser brings you a spare guitar
give guitar

verb ask_woman A_Guitar
!visible gloves
say "Send the guitarist if you know them"

thing guitar
tags portable
cverbs Play

verb Play guitar
at stage
goto request
say You give your best performance, a folk song you learned from your grandfather, everyone you ever sang this to felt cheered up, yet the crowd doesn't seems too attentive. From a corner you hear someone say "I thought they were a band".

verb Play guitar
at backstage
say Some passerby give you an encouraging look, you notice others tuning their instruments

room request Within the occasional booing noises you hear a few shouts of "sing something pop, "sing something we knows, oooooo", "Did anyone see my wallet?"
verbs Sing_A_Pop_Song Refuse

thing The_Manager 
desc She's showing you a thumbs up sign from the backstage.
loc request

verb Sing_A_Pop_Song
say You put your heart and soul into it as you see everyone's eyes glaze with passion
goto question
hide guitar
hide gloves
hide overcoat
hide helmet

verb Refuse
say Passion is something to be cherished, a dream without passion is just being derisive to it. You refuse to sing outside the genre you are passionate about.
goto question
hide guitar
hide gloves
hide overcoat
hide helmet

#temp =============
room question A white room with no sounds, and nothing else in sight, but wait ... if you squint ... you can see something like a microphone

thing microphone 
desc An ordinary microphone, it's wires wave with the wind, almost as if it's calling you towards itself.
loc question
verbs Take_it_in_your_hands_and_sing_your_heart_out Stand_before_it_and_sing_your_heart_out

verb Take_it_in_your_hands_and_sing_your_heart_out
say You are finally awake!, perhaps the dream helped you clear your mind a bit, perhaps it didn't. What you choose to do from here on out is your decision and yours only. Thank you for playing.
run lyrics
goto End

verb Stand_before_it_and_sing_your_heart_out
say You wake up from your dream, perhaps it helped you clear your mind a bit, perhaps it didn't. What you choose to do from here on out is your decision and yours only. Thank you for playing.
run lyrics
hide note
hide envelope
goto End

room End You have finally reached the end of this game. I hope you enjoyed it. You can restart the game and check out the choices you could have made differently. Or perhaps read more about it in the About section.

room exit Everything feels empty, yet there is a sense of calmness and serenity

thing envelope
desc It reads "A way out", seems to be filled with a decision.
tags portable
loc exit
cverbs open

verb open envelope
die You find yourself at peace with your decision to leave your music career. You look forward to what other adventures life has in offer for you. The dream ends disappointingly in your attempt to find a quick exit. GAME OVER

thing note 
prop desc A note from your so called manager, at least he got you this audition, forming the band might have been his idea.
loc changingRoom
tags portable
cverbs open

verb open note
say "Your pianist won't be making it today, get your guitar and your drummer to the stage." - <i>With Love<i>

thing wardrobe
desc A wardrobe for costumes with a mirror surrounded my lights, the mirror is too dark.
loc changingRoom
verbs open

verb open wardrobe
put overcoat changingRoom
put helmet changingRoom
put gloves changingRoom
say A bunch of costumes fall out.
setverb close wardrobe
write wardrobe.verbs close

verb close wardrobe
say "Ouch! my fingers!" you shout as you fail to close the wardrobe.

thing overcoat 
prop desc Rappers and pop idols often popularise such fasion genres
tags wearable portable

thing gloves 
prop desc Fingerless gloves, you used them when playing the guitar
tags wearable portable

thing helmet 
prop desc DJ's use it as a gimmick
tags wearable portable

thing drummer Betty The Drummer
desc Your genius drummer who is in no shape to be performing today
loc secondBathroom
tags alive female conversation
prop start_conversation She grunts for a second seemingly falling asleep again
prop end_conversation She gives no response.

setverb ask_drummer Performance
verb ask_drummer Performance
say Read...yy!!

setverb ask_drummer Guitar 
verb ask_drummer Guitar
say "Ain't seen ... what!"

#------------------------------